home *** CD-ROM | disk | FTP | other *** search
/ Almathera Ten Pack 3: CDPD 3 / Almathera Ten on Ten - Disc 3: CDPD3.iso / scope / 076-100 / scopedisk83 / beep103 / beep103.asm < prev    next >
Encoding:
Assembly Source File  |  1995-03-19  |  4.9 KB  |  225 lines
  1. ******************************************************************
  2. *                                 *
  3. *    Beep. By David Jenkins                     *
  4. *                                 *
  5. ******************************************************************
  6.  
  7.      nolist
  8.           include  "exec/types.i"
  9.           include  "exec/io.i"
  10.           include  "exec/libraries.i"
  11.           include  "exec/memory.i"
  12.           include  "exec/execbase.i"
  13.           include  "offsets/rom.ofs"
  14.       include  "devices/audio.i"    
  15.     list
  16.  
  17. sysbase    equ    4
  18. * 
  19. * Get space for variables
  20.     bra    start
  21.     dc.b    'Beep 1.03'
  22.     dc.b    '25/Jan/89'
  23. start
  24.     moveq    #5,d6
  25.     moveq    #5,d5
  26.     cmpi.b    #10,(a0)    any data
  27.     beq    noparm        no    
  28.     move.b    (a0),d6        pitch
  29.     cmpi.b    #10,1(a0)    any data
  30.     beq    noparm        no
  31.     move.b    2(a0),d5    duration
  32.  
  33. noparm
  34.     movea.l    4,a6            exec base
  35.     move.l  #lengthvar,d0        size of structure
  36.     move.l  #MEMF_CLEAR+MEMF_PUBLIC,d1 memory type = CLEAR and PUBLIC
  37.     jsr     AllocMem(a6)    call AllocMem
  38.     move.l    d0,a5        keep it
  39.     bne    ok1
  40.     moveq    #8,d0
  41.     rts
  42.  
  43. ** get port space for audio device
  44. ok1
  45.     movea.l    4,a6            exec base
  46.     moveq   #MP_SIZE,d0        size of structure
  47.     move.l  #MEMF_CLEAR+MEMF_PUBLIC,d1 memory type = CLEAR and PUBLIC
  48.     jsr     AllocMem(a6)    call AllocMem
  49.  
  50.     move.l  d0,audioport(a5)    save  Port
  51.     bne    gotsp
  52.     moveq    #8,d0
  53.     rts            Big trouble. give up
  54.  
  55.  
  56. ** fill in audio port fields 
  57.  
  58. gotsp    movea.l    audioport(a5),a1
  59.     move.b  #NT_MESSAGE,LN_TYPE(a1) LN_TYPE = NT_MESSAGE(5)
  60.     move.l    #audioportname,LN_NAME(a1)    name
  61.  
  62. * allocate a signal bit
  63.  
  64.         move.l  sysbase,a6      Exec Lib Ptr
  65.     moveq.l    #-1,d0            any signal will do
  66.     jsr    AllocSignal(a6)
  67.     moveq.l    #0,d1            convert signum to a mask
  68.     bset.l    d0,d1
  69.     move.l    d1,d7            stash  sig bit
  70.  
  71.     movea.l    audioport(a5),a1
  72.     move.b    d0,MP_SIGBIT(a1)    save signal bit
  73.  
  74. * Find what task we are in, and install it in the msg ports
  75.  
  76.     sub.l   a1,a1           my task
  77.         jsr     FindTask(a6)
  78.     movea.l    audioport(a5),a1
  79.     move.l    d0,MP_SIGTASK(a1)    task pointer
  80.  
  81.  
  82. ** add  ports
  83.  
  84.         move.l   audioport(a5),a1     Message Port
  85.         jsr      AddPort(a6)   Add another Port to list
  86.  
  87. ** Set up audio IOReq structures
  88.     
  89.  
  90.     lea    audioreq(a5),a1    audio IORequest
  91.     move.b  #NT_MESSAGE,LN_TYPE(a1) LN_TYPE = NT_MESSAGE(5)
  92.     move.b  #0,LN_PRI(a1)     LN_PRI = 0
  93.     move.l  audioport(a5),MN_REPLYPORT(a1) move in message port pointer
  94.  
  95.  
  96. ** open audio device 
  97.  
  98.  
  99. * allocate a channel
  100.  
  101.     lea    audioreq(a5),a1        IOReq
  102.     move.b    #90,LN_PRI(a1)        set priority
  103.     move.l    #channel,ioa_Data(a1)     ask for channel
  104.     move.l    #4,ioa_Length(a1)    set length to do allocate
  105.     move.w    #ADCMD_ALLOCATE,IO_COMMAND(a1) get channel
  106.  
  107.     lea    audioname,a0        audio device name
  108.     moveq    #0,d0            unit number        
  109.     lea    audioreq(a5),a1        IOReq
  110.     moveq    #0,d1            flags
  111.     jsr    OpenDevice(a6)    
  112.     lea    audioreq(a5),a1        IOReq
  113.     cmpi.b    #0,IO_ERROR(a1)        ok?
  114.     beq.s    beepset            yes
  115.     moveq    #0,d0
  116.     move.b    IO_ERROR(a1),d0
  117.     rts
  118.  
  119. * set up for beep
  120.  
  121. beepset    move.l  #2,d0        size of buffer
  122.     move.l  #MEMF_CLEAR+MEMF_CHIP,d1 chip memory 
  123.     JSR     AllocMem(a6)    call AllocMem
  124.     tst.l    d0        got memory?
  125.     beq    nomem        no
  126.     movea.l    d0,a4        keep memory address
  127.     move.w    #$7f81,0(a4)    nice square wave
  128.  
  129. redo    lea    audioreq(a5),a1        IOaudio
  130.     move.b    #ADIOF_PERVOL,IO_FLAGS(a1) new period and volume
  131.     move.l    a4,ioa_Data(a1)        data
  132.     move.l    #2,ioa_Length(a1)    length
  133.     moveq    #0,d0
  134.     moveq    #0,d1
  135.     move.b    d6,d0
  136.     and.b    #$f,d0
  137.     bne.s    1$
  138.     move.b    #5,d0
  139. 1$    move.b    d0,d1    
  140.     mulu    #1000,d0
  141.     move.w    d0,ioa_Period(a1)    set period
  142.     moveq    #0,d0
  143.     move.b    d5,d0
  144.     and.b    #$f,d0
  145.     bne.s    2$
  146.     move.b    #5,d0
  147. 2$    mulu    #100,d0
  148.     divu    d1,d0            calculate cycles
  149.     move.w    #64,ioa_Volume(a1)    loud
  150.     move.w    d0,ioa_Cycles(a1)    how long
  151.     move.w    #CMD_WRITE,IO_COMMAND(a1) write
  152.     BEGINIO
  153.     
  154.  
  155.     move.l    d7,d0            wait for signal
  156.     jsr    Wait(a6)        call wait
  157.  
  158. getnext    move.l    audioport(a5),a0    get message form audio port
  159.     movea.l    4,a6        set Exec base
  160.     jsr     GetMsg(A6)    call GetMsg
  161.     tst.l    d0        any more?
  162.     bne.s    getnext        yes
  163.  
  164.     lea    audioreq(a5),a1
  165.     move.b    #0,IO_FLAGS(a1)
  166.     move.w    #ADCMD_WAITCYCLE,IO_COMMAND(a1) wait for end
  167.     BEGINIO
  168.  
  169.     move.l    d7,d0            wait for signal
  170.     jsr    Wait(a6)        call wait
  171.  
  172.  
  173. getnext2 move.l    audioport(a5),a0    get message form audio port
  174.     movea.l    4,a6        set Exec base
  175.     jsr     GetMsg(A6)    call GetMsg
  176.     tst.l    d0        any more?
  177.     bne.s    getnext2    yes
  178.  
  179.     lea    audioreq(a5),a1
  180.     move.b    IO_ERROR(a1),ret(a5)
  181.  
  182.     moveq    #0,d0
  183.     move.b    MP_SIGBIT+audioreq(a5),d0
  184.     JSR     FreeSignal(A6)        FreeSignal
  185.  
  186.     movea.l a4,a1    audio data
  187.     moveq   #2,D0    size of structure
  188.     jsr     FreeMem(A6)    call FreeMem
  189.  
  190.  
  191. nomem    lea    audioreq(a5),a1    audio IORequest
  192.     JSR     CloseDevice(a6)    call CloseDevice
  193.  
  194. bye     movea.l  audioport(a5),a1      Remove the timer Port
  195.         jsr      RemPort(a6)
  196.  
  197.     movea.l audioport(a5),a1    audio port
  198.     moveq   #MP_SIZE,D0    size of structure
  199.     jsr     FreeMem(A6)    call FreeMem
  200.  
  201.     moveq    #0,d0
  202.     move.b    ret(a5),d2
  203.     move.l    a5,a1
  204.     move.l  #lengthvar,D0    size of structure
  205.     jsr     FreeMem(A6)    call FreeMem
  206.     move.l    d2,d0
  207.     rts
  208.  
  209.     cnop    0,4
  210. channel    dc.l    $01020408
  211.  
  212.     cnop    0,4
  213. audioname dc.b    'audio.device',0
  214.  
  215.     cnop    0,4
  216. audioportname dc.b 'Audiodj',0
  217.         
  218.         offset 0
  219. startvar
  220. audioreq    ds.b    ioa_SIZEOF
  221. audioport    ds.l    1        port address
  222. ret        ds.b    1
  223. lengthvar    equ    *-startvar
  224.         end
  225.